root/grabbers/oztivo @ 62

#!/usr/bin/perl -w

# OzTivo grabber

my $version = '0.5';

# Requires configuration!
# 1. Register at http://www.tvguide.org.au/
# 2. Create file "oztivo.conf" containing the line "username:password"
#    (no quotation marks), e.g. tomdaniels:qwerty09
#
# Changelog:
# 0.1   : Yucky little initial version
# 0.2   : --ready option
# 0.3.  : Don't log password
# 0.4   : Changed password filename
# 0.5   : Identify user agent; support gzip compression; turn off 
#         output buffering

use strict;

use LWP::UserAgent;
use Cwd;
use Getopt::Long;

my $config_file = cwd() . "/oztivo.pw";
my $output_file = cwd() . "/oztivo.xmltv";
my $channels_file;
my $channels;
my @clist;
my $ver;
my $ready;
my $desc;

print "OzTivo Grabber v$version\n";

$| = 1;

GetOptions( 
            'channels_file=s'   => \$channels_file,
            'output=s'          => \$output_file,
            'version'           => \$ver,
            'ready'             => \$ready,
            'desc'              => \$desc
          );

exit 0 if ($ver);

print "Reading configuration file $config_file.\n";

open(CONF, $config_file)
    or die "Unable to read config file $config_file: $!";
my $line = <CONF>;
close CONF;

unless ($line =~ /^(.*):(.*)$/)
{
    die "Unable to parse config file!\n" .
        "Should be in format: username:password\n";
}
my ($user, $pw) = ($1, $2);

exit 0 if ($ready);

unless ($channels_file)
{
    die "No --channels_file specified.\n";
}

unless( -r $channels_file)
{
    die "Unable to read channels file $channels_file: $!";
}
local (@ARGV, $/) = ($channels_file);
eval <>;
die "\nError in channels file!\nDetails:\n$@" if ($@);

# Create a list of channel names from longest to shortest
@clist = sort { length $b <=> length $a } keys %$channels;
print "Channels: @clist.\n";

my $ua = LWP::UserAgent->new();
$ua->agent("Shepherd OzTivo Grabber/$version");
$ua->default_header('Accept-Encoding' => 'gzip');

my $fn = "http://$user:YOURPASSWORD\@minnie.tuhs.org/tivo-bin/xmlguide.pl";
print "Retrieving $fn...\n";

$fn =~ s/YOURPASSWORD/$pw/;

my $response = $ua->get($fn);
unless ($response->is_success())
{
    print "Download failed.\n" . $response->status_line() . "\nExiting.\n";
    exit;
}
my $data = $response->content();
print "Downloaded " . int((do {use bytes; length($data)}) / 1024) . "KB.\n";

if ($response->header('Content-Encoding')
        and
    $response->header('Content-Encoding') eq 'gzip')
{
    print "Unzipping.\n";
    $data = Compress::Zlib::memGunzip($data);
    #$data = Compress::Zlib::memGunzip($response->content());
}

print "Transforming XMLTVIDs.\n";

$data =~ s/channel="(.*)"/'channel="'.subme($1).'"'/ge;

print "Writing output.\n";

open (OUT, ">$output_file");
print OUT $data;
close OUT;

print "Done.\n";

sub subme
{
    my $station = shift;

    foreach (@clist)
    {
        return $channels->{$_} if ($station =~ /$_/i);
    }
    print "Warning: station \"$station\" unknown.\n";
    return $station;
}