root/postprocessors/augment_timezone @ 641

#!/usr/bin/perl -w

# Augment XMLTV start/stop times with the local timezone if MythTV's
# TimeOffset setting is anything other than "None"
#  * to be used as a postprocessor for XMLTV data
#  * can be used in conjunction with 'shepherd' XMLTV reconciler or standalone
#    (pipe-through)
#  * no configuration necessary
#
#  input XMLTV files will either have programme start/stop with or without
#  timezones.  If no timezone is present, Shepherd assumes the input
#  start/stop times are in 'localtime'.
#
#  If MythTV's "TimeOffset" setting is set to anything other than 'None',
#  this can cause programming information to be out:
#   - if set to 'All', all programs will be out by the difference between
#     GMT and locatime ('All' means MythTV is expecting all start/stop times
#     in GMT)
#   - if explicitly set to GMT +/- XX then this will cause programming to
#     be out whenever there is a switchover to/from daylight savings
#
#  this postprocessor addresses this by explicitly putting a timezone
#  on every programme that doesn't already have one, BUT ONLY IF
#  MythTV is configured to anything other than 'None'.
#
#  provided your unix system is configured into the correct timezone,
#  this will work just fine including boundaries crossing daylight savings.
#
#  it means that it doesn't matter if MythTV's "TimeOffset" is set to
#  'All' or 'None', or something inbetween, the data will be right regardless.

use strict;
my $progname = "augment_timezone";
my $version = "0.12";

use XMLTV;
use POSIX qw(strftime mktime);
use Getopt::Long;
use DBI;
use IO::File;

$| = 1;
my $dbh;
my %stats;

my $opt = { };
$opt->{output_file} =   "output.xmltv";
$opt->{mysql_file} =    "/usr/local/share/mythtv/mysql.txt".
                        ":/usr/share/mythtv/mysql.txt".
                        ":$ENV{HOME}/.mythtv/mysql.txt".
                        ":/home/mythtv/.mythtv/mysql.txt".
                        ":/root/.mythtv/mysql.txt".
                        ":/etc/mythtv/mysql.txt";

$opt->{debug} =                 0;

# parse command line
GetOptions(
        'output=s'              => \$opt->{output_file},
        'mysql_file=s'          => \$opt->{mysql_file},
        'timeoffset=s'          => \$opt->{timeoffset},

        'region=i'              => \$opt->{region},             # ignored
        'days=i'                => \$opt->{days},               # ignored
        'offset=i'              => \$opt->{offset},             # ignored
        'timezone=s'            => \$opt->{timezone},           # ignored
        'channels_file=s'       => \$opt->{channels_file},      # ignored
        'config-file=s'         => \$opt->{configfile},         # ignored

        'help'                  => \$opt->{help},
        'verbose'               => \$opt->{help},
        'version'               => \$opt->{version},
        'ready'                 => \$opt->{ready},
        'desc'                  => \$opt->{desc},
        'v'                     => \$opt->{version});

printf "%s v%s\n",$progname,$version;

if ($opt->{version} || $opt->{desc} || $opt->{help} || $opt->{ready} ||
    $opt->{output_file} eq "") {
        printf "Automatically adjust the XMLTV start/stop timezone based on MythTV's\n".
            "TImeOffset setting.\n" if $opt->{desc};

        printf "$progname is ready for operation.\n" if ($opt->{ready});

        printf "No --output file specified.\n" if ($opt->{output_file} eq "");

        if ($opt->{help} || $opt->{output_file} eq "") {
                print<<EOF

usage: $0 [options] {FILE(s)}

Supported options include:
  --output={file}      Send final XMLTV output to {file} (default: $opt->{output_file})
  --mysql_file={file}  File where we look for mythtv database user/pass/dbi (default: $opt->{mysql_file})
  --timeoffset={s}     Specify MythTV's setting, rather than try to look it up
                       in MythTV's database. (E.g. "Auto", "None", "+1000")

EOF
;
        }
        exit(0);
}

&get_database_settings unless ($opt->{timeoffset});

$opt->{timeoffset} = "None" if (!defined $opt->{timeoffset});
if ($opt->{timeoffset} eq "None") {
        print " - MythTV's TimeOffset setting is set to \"None\". No need to do anything.\n";
} else {
        printf " - MythTV's TimeOffset setting is set to \"%s\". Adding timezones.\n",$opt->{timeoffset};
}

my %writer_args = ( encoding => 'ISO-8859-1' );
my $fh = new IO::File(">".$opt->{output_file}) || die "can't open $opt->{output_file} for writing: $!";
$writer_args{OUTPUT} = $fh;

my $writer = new XMLTV::Writer(%writer_args);
$writer->start( {
        'source-info-name' => "$progname $version",
        'generator-info-name' => "$progname $version"} );

foreach my $file (@ARGV) {
        printf " - parsing: %s\n", ($file eq "-" ? "(from-stdin, hit control-D to finish)" : $file);
        XMLTV::parsefiles_callback(undef, undef, \&channel_cb,\&programme_cb, $file);
}

$writer->end();

printf "Finished parsing, output in $opt->{output_file}\n";
printf "STATS: TimeOffset=".$opt->{timeoffset};
foreach my $k (keys %stats) {
        printf ", %d %s", $stats{$k}, $k;
}
printf "\n";

exit(0);

##############################################################################

sub channel_cb( $ )
{
        my $c = shift;
        # printf "got channel ".Dumper($c);
        $writer->write_channel($c);
}

##############################################################################

sub programme_cb( $ )
{
        my $prog=shift;

        if ($opt->{timeoffset} ne "None") {
                # if there is no timezone present in start time, put one there
                if (($prog->{start} !~ /\+/) && ($prog->{start} !~ /\-/)) {
                        $prog->{start} = POSIX::strftime("%Y%m%d%H%M00 %z",localtime(parse_xmltv_date($prog->{start})));
                        $stats{start_tz_added}++;
                }

                # if there is no timezone present in stop time, put one there
                if (($prog->{stop} !~ /\+/) && ($prog->{stop} !~ /\-/)) {
                        $prog->{stop} = POSIX::strftime("%Y%m%d%H%M00 %z",localtime(parse_xmltv_date($prog->{stop})));
                        $stats{stop_tz_added}++;
                }
        }

        $writer->write_programme($prog);
}

##############################################################################

# strptime type date parsing - BUT - if no timezone is present, treat time
# as being in localtime rather than the various other perl implementation
# which treat it as being in UTC/GMT

sub parse_xmltv_date
{
        my $datestring = shift;
        my @t; # 0=sec,1=min,2=hour,3=day,4=month,5=year,6=wday,7=yday,8=isdst
        my $tz_offset = 0;

        if ($datestring =~ /^(\d{4})(\d{2})(\d{2})(\d{2})(\d{2})/) {
                ($t[5],$t[4],$t[3],$t[2],$t[1],$t[0]) = (int($1)-1900,int($2)-1,int($3),int($4),int($5),0);
                ($t[6],$t[7],$t[8]) = (-1,-1,-1);

                my $e = mktime(@t);

                # if input data has a timezone offset, then offset by that
                if ($datestring =~ /\+(\d{2})(\d{2})/) {
                        $tz_offset = calc_gmt_offset($e) - (($1*(60*60)) + ($2*60));
                } elsif ($datestring =~ /\-(\d{2})(\d{2})/) {
                        $tz_offset = calc_gmt_offset($e) + (($1*(60*60)) + ($2*60));
                }

                return ($e+$tz_offset) if ($e > 1);
        }
        return undef;
}

##############################################################################

# given a particular date (in epoch time), return the local timezone offset
# on that date in -/+ seconds from GMT

sub calc_gmt_offset
{
        my $e = shift;
        my $gmt_offset;

        my $tzstring = strftime("%z", localtime($e));
        $gmt_offset = (60*60) * int(substr($tzstring,1,2));     # hr
        $gmt_offset += (60 * int(substr($tzstring,3,2)));       # min
        $gmt_offset *= -1 if (substr($tzstring,0,1) eq "-");    # +/-

        return $gmt_offset;
}

##############################################################################

sub find_database_settings_file
{
        foreach my $cfgfile (split(/:/,$opt->{mysql_file})) {
                return $cfgfile if ((-f $cfgfile) && (-r $cfgfile));
        }

        printf "\nWARNING: Could not find MythTV mysql.txt config file\n".
               "         (looked in ".$opt->{mysql_file}.")\n".
               "         Assuming MythTV's timezone is \"None\".\n".
               "         *** If this is wrong, guide data may be in wrong timezone! ***\n\n";
        $stats{missing_mysql_database_file}++;
        return undef;
}

##############################################################################

sub get_database_settings
{
        my $cfgfile = &find_database_settings_file;
        return if (!defined $cfgfile);

        #
        # find database settings
        #

        if (!(open(F,"<$cfgfile"))) {
                print "WARNING: could not read $cfgfile: $!\n".
                      "Won't augment any timezones!\n";
                $stats{mysql_database_file_unreadable}++;
                return;
        }

        while (<F>) {
                chop;

                if ($_ =~ /^DBHostName=(.*)$/) {
                        $opt->{dbhost} = $1;
                } elsif ($_ =~ /^DBUserName=(.*)$/) {
                        $opt->{dbuser} = $1;
                } elsif ($_ =~ /^DBPassword=(.*)$/) {
                         $opt->{dbpass} = $1;
                } elsif ($_ =~ /^DBName=(.*)$/) {
                        $opt->{dbname} = $1;
                }
        }
        close(F);

        #
        # look up the timeoffset setting
        #

        if (!($dbh = DBI->connect("dbi:mysql:database=".$opt->{dbname}.":host=".$opt->{dbhost},$opt->{dbuser}, $opt->{dbpass}))) {
                print "WARNING: Couldn't connect to database ".$opt->{dbname}.": $!\n".
                      "         Won't augment any timezones!\n";
                $stats{mysql_database_connect_failed}++;
                return;
        }

        my $q = "SELECT data FROM settings WHERE value LIKE 'TimeOffset'";
        if (!($opt->{timeoffset} = $dbh->selectrow_array($q))) {
                print "WARNING: Couldn't query database: $q: $!\n".
                      "         Won't augment any timezones!\n";
                $stats{mysql_database_query_failed}++;
                return;
        }
}