root/references/Shepherd/MythTV.pm @ 680

#!/usr/bin/perl
#
# Shepherd::MythTV library
#
# This module provides some library functions for Shepherd components,
# relieving them of the need to duplicate functionality.
#
# To use this library, components simply need to include the line:
#
#   use Shepherd::MythTV;

package Shepherd::MythTV;

use DBI;

my $version = '0.1';

my $db;

sub find_database_settings_file
{
    my $cfgfile = shift;

    $cfgfile = &standard_mysql_locations unless ($cfgfile);

    foreach my $f (split(/:/,$cfgfile)) 
    {
        return $f if ((-f $f) && (-r $f));
    }

    print "\nWARNING: Could not find MythTV mysql.txt config file!\n".
          "Looked in: $cfgfile\n";
    return undef;
}

sub standard_mysql_locations
{
    return "/usr/local/share/mythtv/mysql.txt".
           ":/usr/share/mythtv/mysql.txt".
           ":$ENV{HOME}/.mythtv/mysql.txt".
           ":/home/mythtv/.mythtv/mysql.txt".
           ":/root/.mythtv/mysql.txt".
           ":/etc/mythtv/mysql.txt";
}

# Find MythTV database settings
# 
sub setup
{
    my $cfgfile = shift;

    $cfgfile = &find_database_settings_file unless ($cfgfile);
    return if (!defined $cfgfile);

    unless (open(F,"<$cfgfile")) 
    {
        print "ERROR: Couldn't read $cfgfile: $!\n";
        return undef;
    }

    print "Reading MythTV DB settings from: $cfgfile\n";

    while (<F>) 
    {
        chomp;
        $db->{$1} = $2 if ($_ =~ /^(DB.*)=(.*)/);
    }
    close(F);
}

# 
# Send an SQL query to the MythTV DB. Will try standard locations to 
# find the MythTV mysql.txt file; if you want to specify a non-standard
# location, first call Shepherd::MythTV::setup($file_location), where
# $file_location is a colon-separated string of (potential) filenames.
#
# Note that data is returned in array form.
#
sub query
{
    my $sql = shift;

    &setup unless ($db);

    unless ($db->{DBName} and $db->{DBHostName} and $db->{DBUserName} and $db->{DBPassword})
    {
        print "ERROR: Missing essential DB connection info.\n";
        return undef;
    }

    my $dbh = DBI->connect(
                "dbi:mysql:database=".$db->{DBName}.":host=".$db->{DBHostName},
                $db->{DBUserName}, $db->{DBPassword});
    unless ($dbh) 
    {
        print "WARNING: Couldn't connect to database ".$opt->{dbname}.": $!\n";
        return undef;
    }
    return $dbh->selectrow_array($sql);
}

1;